import fotos.Foto;
class fotos.Imagenes {
	//Aqui sabre el ambito en el que estoy, no es bueno usar _root
	var ruta_mc:MovieClip;
	//En esta variable se cargara el titulo de la galeria
	private var tit:String;
	//Aqui el numero de imagenes que tiene
	private var nImg:Number;
	//Fotografia grande
	public var foto:Foto;
	//Esta sera nuestra variable de paginación de fotos
	private var paginas:Array;
	//Esta dira la pagina actual
	private var pActual:Number;
	//Hilos de aparición
	private var hilos:Array;
	/*Evento lanzando al terminar de cargar
											A que es una manera creativa de crear eventos, no? ;)*/
	public var onCarga:Function;
	//Constructor de la clase
	function Imagenes(archXML:String, ruta:MovieClip) {
		var conf_xml:XML;
		tit = new String();
		nImg = new Number();
		pActual = new Number();
		onCarga = null;
		ruta_mc = ruta;
		_global.esto = this;
		conf_xml = new XML();
		conf_xml.ignoreWhite = true;
		conf_xml.onLoad = cargarXML;
		conf_xml.load(archXML);
	}
	//función asignada a objeto XML para cargar
	private function cargarXML(exito:Boolean) {
		if (exito) {
			var nodo:XML = new XML();
			//Extraño, inconcluso pero necesario Cast
			nodo = XML(this);
			_global.esto.titulo = nodo.firstChild.childNodes[1].firstChild.nodeValue;
			_global.esto.nImagenes = nodo.firstChild.childNodes[0].firstChild.nodeValue;
			_global.esto.onCarga();
		} else {
			trace("Error al cargar XML");
		}
	}
	//repagina los thumbnails
	public function paginar():Void {
                var imagenesPagina:Number=12;
		var i:Number;
		var tam:Number;
		var mod:Number;
		tam = parseInt(String(nImagenes/imagenesPagina));
		paginas = new Array(tam);
		for (i=0; i<paginas.length; i++) {
			paginas[i] = imagenesPagina;
		}
		mod = nImagenes%imagenesPagina;
		if (mod) {
			paginas[tam] = mod;
		}
	}
	//Redibuja las fotos en el escenario
	public function cambiarPagina(pagina:Number) {
                var imagenesPagina:Number=12;
		var i:Number;
		var elem:Number;
		var init:Object;
		elem = paginas[pagina-1];
		hilos = new Array(elem);
		for (i=0; i<imagenesPagina; i++) {
			ruta_mc["mFoto"+i].removeMovieClip();
		}
		for (i=0; i<elem; i++) {
			init = new Object();
			init = calcularPos(i);
			init.elem = i;
			init.img = i+(imagenesPagina*(pagina-1));
			hilos[i] = setInterval(this.materializar, 20*(i+1), init);
			init = null;
		}
	}
	//Materializa cada imagen en el escenario
	private function materializar(initObj:Object):Void {
		_global.esto.ruta_mc.attachMovie("mFoto", "mFoto"+initObj.elem, initObj.elem+1, initObj);
		clearInterval(_global.esto.hilos[initObj.elem]);
	}
	//Calcula la posición en la que debe aparecer cada objeto
	private function calcularPos(nObjeto:Number):Object {
                var anchoMini:Number=100;
                var altoMini:Number=90;
                var imagenesLinea:Number=4;
		nObjeto++;
		var obj:Object;
		obj = new Object();
		obj._x = obj._y=new Number();
		if ((nObjeto%imagenesLinea) == 0) {
			obj._x = imagenesLinea;
			obj._y = parseInt(String(nObjeto/imagenesLinea))-1;
		} else {
			obj._x = nObjeto%imagenesLinea;
			obj._y = parseInt(String(nObjeto/imagenesLinea));
		}
		obj._y;
		obj._y = _global.initY+((altoMini+20)*(obj._y));
		obj._x = _global.initX+((anchoMini+19)*(obj._x-1));
		return obj;
	}
	public function openImg(imagen:Number):Void {
		ruta_mc.createEmptyMovieClip("drw_mc", ruta_mc.getNextHighestDepth());
		ruta_mc.drw_mc._x = ruta_mc.drw_mc._y=0;
		ruta_mc.drw_mc.beginFill(0x999999, 50);
		ruta_mc.drw_mc.moveTo(0, 0);
		ruta_mc.drw_mc.lineTo(ruta_mc._width, 0);
		ruta_mc.drw_mc.lineTo(ruta_mc._width, ruta_mc._height);
		ruta_mc.drw_mc.lineTo(0, ruta_mc._height);
		ruta_mc.drw_mc.endFill();
		ruta_mc.drw_mc.useHandCursor = false;
		ruta_mc.drw_mc.onRelease = function() {
			//
		};
		foto = new Foto(imagen, ruta_mc);
	}
	public function closeImg():Void {
		ruta_mc.drw_mc.removeMovieClip();
		ruta_mc.pop_mc.removeMovieClip();
		foto = null;
		delete foto;
	}
	//Setters | Getters
	public function get nImagenes():Number {
		return this.nImg;
	}
	public function set nImagenes(numero:Number):Void {
		this.nImg = numero;
	}
	public function get titulo() {
		return ".:: "+this.tit+" ::.";
	}
	public function set titulo(nombre:String):Void {
		this.tit = nombre;
	}
	public function get nPaginas():Number {
		return Number(this.paginas.length);
	}
}