#!/usr/bin/perl -w
# ar-info -- lintian collection script
#
# Copyright © 2009 Stéphane Glondu
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, you can find it on the World Wide
# Web at http://www.gnu.org/copyleft/gpl.html, or write to the Free
# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
# MA 02110-1301, USA.

use strict;
use warnings;

use lib "$ENV{LINTIAN_ROOT}/lib";
use FileHandle;
use Lintian::Command qw(spawn);
use Util qw(fail);

($#ARGV == 2) or fail 'syntax: ar-info <pkg> <type> <dir>';
my ($pkg, $type, $dir) = @ARGV;

if ( -e "$dir/ar-info" ) {
    unlink "$dir/ar-info" or fail "unlink ar-info: $!";
}

# Open before chdir, as unpacked may be a symlink
open INDEX, '<', "$dir/index"
    or fail("cannot open index file: $!");
open OUT, '>', "$dir/ar-info"
    or fail("cannot open ar-info file: $!");

chdir ("$dir/unpacked")
    or fail("cannot chdir to unpacked directory: $!");

while (<INDEX>) {
    chomp;
    next unless /\.a$/;
    my $file = (split(' ', $_, 6))[5];
    next unless -f $file;
    my $opts = { pipe_out => FileHandle->new, err => '/dev/null' };
    spawn($opts, [ 'ar', 't', $file ]);
    print OUT "$file:";
    while (defined($_ = readline($opts->{pipe_out}))) {
        chomp;
        print OUT " $_";
    }
    close($opts->{pipe_out});
    print OUT "\n";
    $opts->{harness}->finish;
}

close(INDEX);
close(OUT) or fail("cannot write ar-info: $!");

# Local Variables:
# indent-tabs-mode: nil
# cperl-indent-level: 4
# End:
# vim: syntax=perl sw=4 sts=4 sr et