/*
	AVISO LEGAL:
	Este código está amparado por las leyes internacionales de derechos de autor 
	y de propiedad intelectual. Queda totalmente prohibida su utilización y/o 
	modificación sin el previo consentimiento de Antares Comunicación Audiovisual
	(www.antares.es) o en proyectos en los que no esté presente.
*/
/*
 [ DATA: ]
 	· initX, initY 	<- coordenadas globales para colocar el puzzle
 	· dimH, dimW 	<- numero de piezas: alto x ancho
 	· movie 		<- imagen a partir de la que hacer el puzzle
 	· ps			<- PositionController que gestiona la posición de los destinos
  
 [ RESPONSABILITIES ]
 	· Crear las distintas instancias de las Fichas
 	· Mandar las coordenadas individuales de cada ficha
  	· Gestionar partidas:
 		· iniciar
 		· Controlar si se ha terminado
 		· Volver a empezar
 
 [ NOTIFICACIONES ]
 	· cuando se coloque una pieza correcamente, pasando como parámetro el número
	  de piezas restantes por colocar
 
 */
import movieclip.PositionController;
import utils.ExtendedRandomPosition;
import sistema.ArrayRandomizer;
import Ficha;
import GestorPuzzle;
import bravo.Contador;
class PuzzleController extends MovieClip {
	// @parameters
	private var dimH:Number = new Number(2);
	//numero fichas alto
	private var dimW:Number = new Number(2);
	//numero fichas ancho
	private var maxH, maxW:Number;
	//tamaño total del puzzle
	public var imageToLoad:String;
	//archivo del que hacer puzzle
	private var secuenciaPosiciones:Array = Array();
	//Será un array de dimH x dimW posiciones
	//que llenaré con strings "w_h", que luego
	//randomizaré para ir poniendo en ese "cuarteado"
	//las fichas
	// @data
	public var widthFicha, heightFicha:Number;
	public var widthZonaInicio, heightZonaInicio:Number;
	private var numFichasToPosition:Number;
	public var gestor:GestorPuzzle;
	public var contador:Contador;
	// @internal usage
	private var pcDestiny:PositionController;
	private var rpFicha:ExtendedRandomPosition;
	private var border_mc, caja_mc:MovieClip;
	// Triggered cuando el puzzle se ha terminado
	[Callback("onGameEnd")]
	public var onGameEnd:Function;
	public function PuzzleController() {
		//border_mc._visible = false;
	}
	public function setDimensions(w:Number, h:Number) {
		var i, j, pos;
		dimW = w;
		dimH = h;
		for (i=0; i<dimW; i++) {
			for (j=0; j<dimH; j++) {
				pos = (i*dimH)+j;
				secuenciaPosiciones[pos] = i+'_'+j;
			}
		}
		this.contador.setMaxAciertos(dimW*dimH);
	}
	public function start(f:String) {
		var it, it2, k;
		var arrPosicion:Array;
		var strPosicion;
		var posX, posY;
	     
		 
		 
		numFichasToPosition = dimH*dimW;
		imageToLoad = f;
		contador.init();
		maxW = border_mc._width;
		maxH = border_mc._height;
		widthFicha = maxW/dimW;
		heightFicha = maxH/dimH;
		widthZonaInicio = (caja_mc._width)/dimW;
		heightZonaInicio = (caja_mc._height)/dimH;
		//Randomizo el array de secuencia
		secuenciaPosiciones = ArrayRandomizer.randomizar(secuenciaPosiciones);
		var foo:Object = {xOffSet:border_mc._x, yOffSet:border_mc._y, initDepth:0, dx:maxW/dimW, dy:maxH/dimH, numCols:dimW};
		pcDestiny = new PositionController(foo);
		foo = {startX:caja_mc._x, startY:caja_mc._y, intervalX:widthZonaInicio, intervalY:heightZonaInicio, offsetX:-widthFicha, offsetY:-heightFicha, initDepth:100};
		rpFicha = new ExtendedRandomPosition(foo);
		for (it2=0; it2<dimH; it2++) {
			for (it=0; it<dimW; it++) {
				//Para hacer la posición aleatoria, tomo el valor del array de secuencia
				k = (it*dimH)+it2;
				strPosicion = secuenciaPosiciones[k];
				//split del string, tengo en 0 la x y en 1 la y
				arrPosicion = strPosicion.split("_");
				posX = Number(arrPosicion[0]);
				posY = Number(arrPosicion[1]);
				var d:MovieClip = createDestiny(pcDestiny.getCoordinates(), it, it2);
				createFicha(rpFicha.getCoordinates(posX, posY), d, it, it2);
			}
		}
	}
	public function getCaja_mc() {
		return this.caja_mc;
	}
	public function createDestiny(foo:Object, w, h):MovieClip {
		var newmc = createEmptyMovieClip("destiny_"+w+"_"+h, foo.depth, foo);
		newmc._x = foo._x;
		newmc._y = foo._y;
		newmc.beginFill(0xeeeeee, 50);
		newmc.lineStyle(1, 0x999999, 60);
		newmc.moveTo(0, 0);
		newmc.lineTo(widthFicha, 0);
		newmc.lineTo(widthFicha, heightFicha);
		newmc.lineTo(0, heightFicha);
		newmc.lineTo(0, 0);
		newmc.endFill();
		return newmc;
	}
	public function createFicha(foo:Object, d:MovieClip, w:Number, h:Number) {
		var k = (h*dimH)+w;
		foo.destiny_mc = d;
		foo.controller = this;
		foo.destiny = "destiny_"+w+"_"+h;
		var a = attachMovie("ficha", "ficha_"+w+"_"+h, foo.depth, foo);
		a.switchOn();
	}
	public function notifyMovement(f:Ficha) {
		numFichasToPosition--;
		if (isGameEnded()) {
			onGameEnd();
		}
	}
	public function isGameEnded():Boolean {
		return !Boolean(numFichasToPosition);
	}
}